Formatting of output from awk

Shell Programming and Scripting
1

Hi;
i m running an command like;

getfacl $(find /home/fstl/testShell/ -type f -ls | awk '{print $11}')

and i m getting outpiut for all files in "testShell" folder as;

# file: home/fstl/testShell/.script1.sh.swp
# owner: root
# group: root
user:fstl:rw-
user:ajay:rw-
group:root:r--
group:bhavani:r--


# file: home/fstl/testShell/test
# owner: fstl
# group: fstl
user:fstl:rw-
user:ajay:rw-
group:root:r--
group:bhavani:r--

supposing der are only 2 files;

but i want to get formatted output like;

filepath:home/fstl/testShell/test
users:fstl,ajay
permissions for users:rw-,rw-
groups:root,bhavani
permissions for groups:r--,r--

for all the files;

is der nay way one can do this using awk, stroing variables or nething
please help me out;

thnks;
Ajay

2

Yes,
add this at the end of your pipeline:

awk -F: 'END { puts( ) }
/^# file:/ {
  if ( f ) puts( )
  sub( /^# file: /, x )
  f = $0; u = up = g = gp = x
  }
/^user:/ {  
  u = u ? u "," $2 : "users" FS $2
  up = up ? up "," $3 : "permissions for users" FS $3
  }
/^group:/ {
  g = g ? g "," $2 : "groups:" $2
  gp = gp ? gp "," $3 : "permissions for groups" FS $3
  }
func puts( ) {  
  print "filepath:" f
  print u; print up
  print g; print gp
  print x
  }' infile