Calculate different between two columns and return high and lower value

Shell Programming and Scripting
1

In database.txt

tourID:name:buyin:buyout
0001:SundayMillion:210:1000000
0002:MondayMillion:115:114
0003:Tuesday:123:0
0004:Thrusday:12412:26

I want the outpout:

The higher value is SundayMillion, proffit 999790 euros.
The lower value is  MondayMillion, proffit 1 euros.
The value more negative is Tuesday, proffit is negative, -123 euros.

I want the difference between $buyin and $buyout in absolute and return the high and lower value.

Thanks

2

Assuming there's no column header line in the actual file.
Not sure if your last metric is correct - my understanding gives me 'Thursday'..

nawk -f raf.awk myFile
raf.awk:

BEGIN {
  FS=":"
}

{
   diffR=$4-$3
   diff=(diffR<0)?-diffR:diffR
   if (higher<diff) {
       higher=diff
       higherA=$2
   }
   if (lower>diff ||FNR==1){
       lower=diff
       lowerA=$2
   }

   if (lowerR>diffR ||FNR==1){
       lowerR=diffR
       lowerRA=$2
   }

}
END {
   printf("The higher value is %s, proffit %d euros.\n", higherA, higher)
   printf("The lower value is %s, proffit %d euros.\n", lowerA, lower)
   printf("The value more negative is %s proffit is negative, %d euros.\n", lowerRA, lowerR)
}
3 
./v12.sh: line 369: nawk: command not found

this is why?

4

use awk or gawk instead.

5

it works with gawk.

Higher works fine but the lower shows me the header of my file:

tourID:name:buyin:buyout

how can i despite the first line?

6 
BEGIN {
  FS=":"
}

FNR!=1{
   diffR=$4-$3
   diff=(diffR<0)?-diffR:diffR
   if (higher<diff) {
       higher=diff
       higherA=$2
   }
   if (lower>diff ||FNR==2){
       lower=diff
       lowerA=$2
   }

   if (lowerR>diffR ||FNR==2){
       lowerR=diffR
       lowerRA=$2
   }

}
END {
   printf("The higher value is %s, proffit %d euros.\n", higherA, higher)
   printf("The lower value is %s, proffit %d euros.\n", lowerA, lower)
   printf("The value more negative is %s proffit is negative, %d euros.\n", lowerRA, lowerR)
}
7

Thanks thanks thanks!! It works=))))